Adding Working Scripts to Items

What it does:

This tutorial will go step-by-step to adding a simple script to an item-- gloves that grant you the Blizzard spell while wearing them.

Create the item

First, you want to create the gloves. Let's say our gloves are Elven Gauntlets of Thalmor origin. The fields I edited are highlighted in red.

Create an Item

Writing the script

Now that the easy part is done, we will move on to the difficult part. From Gameplay at the top select Papyrus Script Manager, right click on a script and select New. You will be greeted with a dialogue box. (You could also add the script from the item window by doing "Add" on the script section and choosing new script that way it will default to the right type)

Create a Script

Because it's an item, it must extend ObjectReference because OnEquipped is an ObjectReference Script. Now we can simply just write out our script and save it.

This is the scriptname:

Scriptname tutGlovesofBlizzardScript extends ObjectReference  
{OnEquip adds a spell}

In order to use things like AddSpell and AddItem, you have to make a property for them in your script. If not you will get an "Undefined variable" error.

Spell Property Blizzard auto

This is our ObjectReference.OnEquipped event. It is important you extend it by ObjectReference in the Scriptname, or else this will not compile properly saying it is "not a valid or non existent function".

Event OnEquipped(Actor akActor)
    if akActor == Game.GetPlayer()
        Game.GetPlayer().AddSpell(Blizzard, true)
    endIf
endEvent

This is simply just another event using the same property to remove the spell when the player unequipped it. We only want them to have the spell if they wear it.

Event OnUnequipped(Actor akActor)
    if akActor == Game.GetPlayer()
        Game.GetPlayer().RemoveSpell(Blizzard)
    endIf
endEvent

So now that our script is finished, we can save it. Hopefully yours compiles as flawlessly as this example.

Attaching the Script

Now, we go back to our gloves, and add the script, edit the property and select the spell that will stand in for the Blizzard property.

Attach the Script

Testing In Game

Now we can test them. I added the gloves in to the game by allowing the players to combine normal elven gauntlets with Frost Salts at the Forge. You can use any method you want to put them in the game. Everything looks good on the gauntlets so far, and when we equip them our script runs successfully.

View Ingame

This concludes the tutorial, and I hope it helped people avoid a lot of frustration.